File:Nuclear Fireball Radius and Temperature.svg
Size of this PNG preview of this SVG file: 600 × 600 pixels. Other resolutions: 240 × 240 pixels | 480 × 480 pixels | 768 × 768 pixels | 1,024 × 1,024 pixels | 2,048 × 2,048 pixels.
Original file (SVG file, nominally 600 × 600 pixels, file size: 51 KB)
 | This is a file from the Wikimedia Commons. Information from its description page there is shown below. Commons is a freely licensed media file repository. You can help. |
Summary
| Description |
English: Diameter and temperature vs. time of the fireball of a 20 kiloton nuclear air burst (near sea-level). Self-generated fit of curves in Glasstone & Dolan, The Effects of Nuclear Weapons (1977).
Deutsch: Durchmesser und Temperatur als Zeitfunktion des Feuerballs einer 20-Kilotonnen-Kernexplosion in der Luft (nahe Meeresniveau). Selbst erzeugter Fit von Kurven aus Glasstone & Dolan, The Effects of Nuclear Weapons (1977). |
| Date | |
| Source | Own work |
| Author | SiriusB |
| Other versions | Nuclear Fireball Radius and Temperature.png |
| SVG development | |
| Source code | Gnuplot codereset
#### Terminal settings
set term svg enhanced size 600,600 font "Helvetica, 16";set output 'fbrt.svg'
#### Mathematical definitions
## Fireball temperature
p0= 2.8526650801 ; q0= 69.18513566
p1=-1.0863702704 ; q1=115.00394909
p2= 4.7729619842 ; q2= 79.77893973
p3=10.026967289 ; q3= 27.50798341
p4= 7.1862268373 ; q4= 4.74096116
p5= 2.2724484357 ; q5= 0.32749001
p6= 0.27143255706
g1(x)=-1.103046*x+1.032988
g2(x)=(((((p6*x+p5)*x+p4)*x+p3)*x+p2)*x+p1)*x+p0
g3(x)=-0.547586*x+3.505928
h1(x)=((((q5*x+q4)*x+q3)*x+q2)*x+q1)*x+q0
g(x) = x<=-2.507 ? g1(x) : x<=-0.686 ? g2(x) : g3(x)
h(x) = x<=-2.22638 ? h1(x) : NaN
fg(x)= 10.**g(log10(x))
fh(x)= 10.**h(log10(x))
## Fireball diameter
rm4=13.; rm1=215.; re=236.; pr=log10(rm1/rm4)/3.; pk=-3.
d(x)=2*((rm4*(10000.*x)**pr)**pk+re**pk)**(1./pk)
#### Format definitions
set tmargin 0.2; set bmargin 2.8; set lmargin 9.6; set rmargin 1
lw1=3.; lw2=1.
unset key
set logscale xy
set xrange [1e-4:10]
set yrange [20:3e5]
set xtics ("10^{-4} " 0.0001,"" 0.0002,"" 0.0003,"" 0.0004,"" 0.0005,\
"" 0.0006,"" 0.0007,"" 0.0008,"" 0.0009,\
"10^{-3} " 0.001,"" 0.002,"" 0.003,"" 0.004,"" 0.005,\
"" 0.006,"" 0.007,"" 0.008,"" 0.009,\
0.01,"" 0.02,"" 0.03,"" 0.04,"" 0.05,"" 0.06,"" 0.07,"" 0.08,"" 0.09,\
0.1,"" 0.2,"" 0.3,"" 0.4,"" 0.5,"" 0.6,"" 0.7,"" 0.8,"" 0.9,\
1,"" 2,"" 3,"" 4,"" 5,"" 6,"" 7,"" 8,"" 9,10)
set ytics (10,"20" 20,"" 30,"" 40,"" 50,"" 60,"" 70,"" 80,"" 90,\
100,"" 200,"" 300,"" 400,"" 500,"" 600,"" 700,"" 800,"" 900,\
1000,"" 2000,"" 3000,"" 4000,"" 5000,"" 6000,"" 7000,"" 8000,"" 9000,\
"10000" 10000,"" 20000,"" 30000,"" 40000,"" 50000,\
"" 60000,"" 70000,"" 80000,"" 90000,\
"100000" 100000,"" 200000,"" 300000,"" 400000,"" 500000,\
"" 600000,"" 700000,"" 800000,"" 900000,\
"10^6 " 1e6)
set grid xtics ytics mxtics lt 1 lw lw2 lc rgb '#A0A0A0'
#### Labels
## Use oblique fonts if available
#set xlabel '{/Oblique t} / s'
set xlabel 't / s'
#set ylabel offset 1,0 '{/Oblique D} / m &{123456789012345} {/Oblique T}_{eff} / K'
set ylabel offset 0.5,0 'D / m &{123456789012345} T_{eff} / K'
#### Plotting
plot fg(x) w l lt 1 lw lw1 lc rgb '#700',\
fh(x) w l lt 1 lw lw1 lc rgb '#F80',\
d(x) w l lt 1 lw lw1 lc rgb '#00F'
reset
|
Licensing
|
I, the copyright holder of this work, release this work into the public domain. This applies worldwide. In some countries this may not be legally possible; if so: I grant anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law. |
File history
Click on a date/time to view the file as it appeared at that time.
| Date/Time | Thumbnail | Dimensions | User | Comment | |
|---|---|---|---|---|---|
| current | 12:53, 21 November 2008 | | 600 × 600 (51 KB) | SiriusB | {{Information |Description={{en|1=Diameter and temperature vs. time of the fireball of a 20 kiloton nuclear air burst (near sea-level). Self-generated fit of curves in Glasstone & Dolan, The Effects of Nuclear Weapons (1977).}} {{de|1=Durchmesser und Temp |
File usage
The following pages on the English Wikipedia use this file (pages on other projects are not listed):
Global file usage
The following other wikis use this file:
- Usage on de.wikipedia.org
